1С:Шина — от установки до использования на реальном проекте

Авторы

Описание продукта «1С:Шина»
Постановка задачи с описанием бизнес‑кейса
Установка и настройка 1С:Шины
Работа в среде разработки «1С:Шина»
1. Описание среды разработки
2. Групповая разработка
Реализация практического бизнес-кейса
1. Обзор схемы разузловки и маршрутизации внутри 1С:Шины
2. Настройка обработки и отправки сообщений на стороне информационных баз 1С
Тесты и нагрузка на сервер
1. Проверка работоспособности процессов интеграции
2. Нагрузочный тест
Логирование действий и анализ проблем
Выводы

Описание продукта «1С:Шина»

1С:Шина — это продукт, который позволяет обеспечить асинхронный обмен между различными информационными системами. «1С:Шина» содержит интерфейсы для взаимодействия с разными информационными системами по различным протоколам (например, FTP, HTTP, JMS, RabbitMQ), в том числе и с системами «1С:Предприятие». Системы, которые позволяют создавать приложения данного класса называются «Сервисной шиной предприятия» (в английской интерпретации Enterprise Service Bus, ESB).

«1С:Шина» обеспечивает маршрутизацию, трансформацию и гарантированную доставку сообщений. Рассмотрим общую схему передачи сообщений при помощи интеграционной шины:

Описание продукта 1С:Шина

Сообщение интеграции на стороне отправителя буферизируется и далее, при условии что интеграционная шина доступна, отправляет его в канал передачи сообщений.
Интеграционная шина получает сообщение интеграции, проводит его маршрутизацию и направляет в канал передачи получателю.
Получатель сообщения считывает сообщение интеграции, помещает его в буфер и вызывает обработчики, которые содержат математику приемки сообщения.

Стоит отметить, что сообщения интеграции отправляются и считываются в асинхронном режиме, когда их отправка из системы-отправителя и доставка в систему-получатель происходит не одновременно, и это в том числе обеспечивает гарантированную доставку сообщений. Сообщение не будет отправлено до тех пор, пока интеграционная шина не будет доступна. Точно также, до тех пор, пока не будет получено подтверждение от 1С:Шины, что сообщение получено, будут выполняться повторные попытки отправить сообщение.

Удобнее всего рассматривать 1С:Шину и задачи, которые она способна решить на практическом примере, что мы и сделаем далее.

Постановка задачи с описанием бизнес‑кейса

Сеть ресторанов осуществляет прием, приготовление, выдачу и доставку заказов. Формирование заказов в информационной системе может происходить несколькими способами:

Непосредственно в ресторане через фронтовую систему «1С:Предприятие 8. Фастфуд. Фронт-офис».
Часть точек принимают заказы в сторонней информационной базе 1С, которая использовалась на предприятии ранее.
Заказы также могут поступать из бота в мессенджере Telegram, данные сериализуются и отправляются по протоколу http.
На предприятии для маршрутизации сообщений уже использовался брокер сообщений RabbitMQ (сообщения передаются в формате AMQP 0.9.1), а также другой брокер, осуществляющий отправку сообщений в формате AMQP 1.0. Необходимо обеспечить считывание и транспортировку сообщений из вышеуказанных брокеров.

В результате наличия большого количества информационных систем, обменивающихся данными о заказах, которые появились на предприятии в разное время, используются два разных формата сообщения, описывающего заказ: старый формат (в виде json) и новый (в виде xml). Отметим, что термины «старый» и «новый» это условность, т. к. в нашем примере на предприятии использовался сначала json, а потом xml.

Пример сообщения в формате json:

{

        "timestamp":  1631693068,

        "source": "jmeters",

        "active": true,

        "type": "ЗаказФронта", 

        "guest_id": "BF5F7F00-001C-11EC-B048-0050560A1F78",

        "status": "received_delivery",

        "delivery_address": ",,,Москва,,Профсоюзная улица,65 к1,,,,,,,,55.6533,37.538,",

        "total_sum": 518,

        "origin": "delivery",

        "payment_info": {

                "pay_type": "CARD",

                "sum": 518,

                "back_sum": 0,

                "total_sum": 518,

                "paid": "true",

                "rrn_code": "41d4d4ae-bd71-752e-8650-5b730242a51e"

        },

        "delivery_info": "",

        "delivery_address_comment": "",

        "items": [

                {

                        "id": 1,

                        "product_id": "88851C16-3872-11EB-A060-7085C286679E",

                        "price": 116,

                        "count": 1,

                        "total_sum": 116,

                        "menu_id": "2ED2CBA1-5A56-11EB-A062-7085C286679E",

                        "status_int": 1

                },

        "seats": 2

}

В поле type указывается назначение заказа: «ЗаказФронта» или «ЗаказБэка». Аналогично в новом формате xml:

<data>

  <timestamp>1631693068</timestamp>

  <source>rabbit</source>

  <doc_id>1895de51-bf34-46a8-922d-a4c3d2b9d2e8</doc_id>

  <active>true</active>

  <type>ЗаказБэка</type>

  <guest_id>BF5F7F00-001C-11EC-B048-0050560A1F78</guest_id>

  <status>received_delivery</status>

  <delivery_address>,,,Москва,,Профсоюзная улица,65 к1,,,,,,,,55.6533,37.538,</delivery_address>

  <total_sum>518</total_sum>

  <origin>delivery</origin>

  <payment_info>

    <pay_type>CARD</pay_type>

    <sum>518</sum>

    <back_sum>0</back_sum>

    <total_sum>518</total_sum>

    <paid>true</paid>

    <rrn_code>41d4d4ae-bd71-752e-8650-5b730242a51e</rrn_code>

  </payment_info>

  <delivery_info/>

  <delivery_address_comment/>

  <items>

    <item>

      <id>1</id>

      <product_id>1895de51-bf34-46a8-922d-a4c3d2b9d2e8</product_id>

      <price>116</price>

      <count>1</count>

      <total_sum>116</total_sum>

      <menu_id>2ED2CBA1-5A56-11EB-A062-7085C286679E</menu_id>

      <status_int>1</status_int>

    </item>

  </items>

  <seats>2</seats>

</data>

Приемниками сообщений выступают информационные базы бэка (1С:УНФ 8. Управление предприятием общепита) и фронта (1С:Предприятие 8. Фастфуд. Фронт-офис) в зависимости от типа заказа, указанного в тексте сообщения интеграции.

Обработка сообщений происходит только в новом формате, то есть, интеграционная шина данных должна обеспечить смену формата в случае необходимости.

При считывании сообщений обмена из сторонних брокеров, в базах-приемниках сообщений идентификаторы товаров в составе заказа могут отличаться от идентификаторов в информационных системах отправителях. Существует база данных, развернутая на СУБД MSSQL, которая содержит таблицу соответствия идентификаторов в различных информационных системах. Необходимо обеспечить преобразование идентификаторов товаров в заказе в случае необходимости, используя данные вышеописанной базы.

Уникальный идентификатор, который необходимо преобразовать содержится в поле product_id.

Также, сторонняя информационная база 1С, ожидает обратную квитанцию об обработке сообщения базой-получателем, необходимо обеспечить ее доставку.

В итоге, предполагаемая схема, описывающая интеграционные процессы на предприятии будет иметь следующий вид:

Схема, описывающая интеграционные процессы на предприятии

Отметим, что данная схема спроектирована отдельно от ее реализации в какой-либо интеграционной шине данных и к продукту «1С:Шина» пока не имеет отношения.

Как видно из схемы, интеграционная шина данных должна обеспечивать преобразование сообщений из старого формата в новый, а также замену идентификаторов товаров в случае, если это требуется. Также она должна маршрутизировать заказ в правильную базу-получатель, в зависимости от его вида, и отправлять обратную квитанцию, если заказ пришел из информационной базы 1С.

Именно на эту схему будем опираться при проектировании и разработке схемы интеграции в продукте «1С:Шина».

Установка и настройка 1С:Шины

Используемая инфраструктура

Схему интеграции будем реализовывать на сервере с процессором Intel^® Xeon^® Gold 6242R CPU @ 3.10GHz и объемом оперативной памяти 320 GB под управлением Microsoft Windows Server 2012 R2.

Отметим, что объем оперативной памяти на нашем сервере избыточен, т. к. за все время тестов, сервер 1С:Шины не занимал места более 15 гигабайт.

Сервер 1С:Шины будет размещаться на одной физической машине с 64 разрядным сервером 1С 8.3.20.1710 и СУБД PostgreSQL 14 для исключения сетевой нагрузки при передаче данных.

Установка и настройка

Новые дистрибутивы 1С:Шины регулярно выходят на портале releases.1c.ru. На данный момент (конец октября 2022 года) доступна версия 2.0.1 (releases.1c.ru/version_files?nick=esb&ver=2.0.1).

Установка и настройка 1С:Шины

Доступны версии как со средой разработки, так и без. Так как мы собираемся разрабатывать схему интеграции с нуля, а не использовать существующую, то скачиваем именно версию со встроенной IDE. Возможность установки дистрибутива без среды разработки может быть использована, например, для того, чтобы выделить отдельно продуктивный сервер 1С:Шины. На нем среда разработки нам будет не нужна, а обновлять приложения мы будем при помощи стандартного механизма импорта, встроенного в консоль управления сервером.

Стоит отметить, что для работы сервера «1С:Шина» необходимо также установить java, как и при установке 1С:EDT. Использование java делает «1С:Шина» кроссплатформенным приложением, поэтому процесс установки, настройки и непосредственной работы сервера с точки зрения конечного пользователя будет идентичен как на ОС Linux, так и на OS Windows.

Установка и настройка 1С:Шины

После установки сервера «1С:Шина» создастся служба 1c-enterprise-esb-with-ide.

Установка и настройка 1С:Шины

Перед запуском службы стоит поговорить о настройках сервера. По умолчанию директория с конфигурационными файлами находится по пути «c:\ProgramData\1C\1CE\instances\
1c-enterprise-esb-with-ide\config».

Установка и настройка 1С:Шины

Подробное описания всех настроек сервера можно посмотреть в документации (its.1c.ru/db/esbdoc
#content:40083:hdoc). Отметим лишь, что для нас самыми полезными настройками оказался файл debug.yaml с настройками сервера отладки, порт для которого по умолчанию был установлен на 8080. Данный порт был занят и служба сервера 1С:Шины не стартовала. После установки порта в настройках на доступный сервер стал работать корректно:

debug:

  enabled: true

  port: 8088

Управление сервером и разработка схем интеграции происходит через веб-интерфейс. По умолчанию для доступа к веб-интерфейсу используется порт 9090. После запуска службы сервера проверяем его работоспособность вбив в строке браузера http://localhost:9090/maintenance
/server/v1/heartbeat.

Установка и настройка 1С:Шины

Далее можно переходить в консоль управления сервером по адресу http://127.0.0.1:9090/console и создавать схемы интеграции. Здесь и в дальнейшем будет использоваться локальный адрес сервера 127.0.0.1, т. к. эксперименты проводились непосредственно на сервере, где установлена «1С:Шина».

Установка и настройка 1С:Шины

В процессе установки и настройки сервера, а также разработки новых схем нам понадобится документация к продукту, которая есть на сайте ИТС (its.1c.ru/db/esbdoc), или же доступна непосредственно из веб-интерфейса 1С:Шины по адресу http://127.0.0.1:9090/docs/
help/index.html

Описание сущностей и терминология

В тексте статьи мы будем оперировать различными сущностями, которые используются в «1С:Шине». Поэтому, давайте разберемся, что они из себя представляют. С полным глоссарием можно ознакомиться в документации (its.1c.ru/db/esbdoc
#content:40033:hdoc), здесь же приведем только самые важные, используемые в статье.

«1С:Шина» предоставляет модель построения приложения. Эта модель основана на том, что вы описываете логику приложения в виде проекта.

Проект — это описание логики приложения, которое может быть исполнено сервером. Создать проект и посмотреть список существующих можно в специальной вкладке в консоли управления сервером.

Описание сущностей и терминология

Приложение — это совокупность проекта и пользовательских данных, исполняемая сервером. Для хранения пользовательских данных приложение использует СУБД. Один и тот же проект может содержать несколько приложений.

Приложение является основной сущностью, которой оперируют пользователи в «1С:Шина». Список приложений можно увидеть на отдельной вкладке в консоли кластера. По каждому приложению можно увидеть его статус, дату создания и последнего обновления, а также перейти в консоль управления конкретным приложением или же в среду разработки:

Описание сущностей и терминология

В консоли кластера существует возможность при создании приложения сразу же создать и новый проект:

Описание сущностей и терминология

Чтобы описать логику приложения, вы добавляете в проект элементы того или иного вида, а также подсистемы, пакеты, модули и ресурсы. Каждый из элементов проекта решает определенный круг задач. Со всеми элементами проекта можно ознакомиться в документации (its.1c.ru/db/
esbdoc/content/40163/
hdoc).

Наиболее часто используемые из элементов:

http-сервис,
общий модуль,
процесс интеграции.

В рамках конкретного приложения необходимо определить и настроить информационные системы — это участники обмена сообщениями, которые подключаются к приложению «1С:Шины» и с его помощью взаимодействуют с другими информационными системами, обмениваясь с ними сообщениями в рамках процесса интеграции.

Вести список информационных систем можно на специальной вкладке в консоли управления приложением:

Описание сущностей и терминология

У каждой информационной системы есть код, наименование и описание. Код должен быть уникальным, по нему отправители сообщений интеграции смогут отфильтровать список получателей:

Описание сущностей и терминология

К серверу 1С:Шины существует возможность подключения внешних СУБД, список которых хранится и настаивается на соответствующей вкладке в консоли сервера:

Описание сущностей и терминология

В качестве СУБД могут выступать такие системы как PostgreSQL и MSSQL Server.

Создание приложения

Для того, чтобы начать разработку, сначала необходимо создать новое приложение, в котором будет настраиваться схема интеграции. Меню создания доступно из консоли управления сервером. Приложение может быть привязано к проекту или же загружено из выгрузки (при условии, что мы предварительно экспортировали созданное приложение):

Создание приложения

Также предлагается выбрать СУБД, в которой будут храниться данные создаваемого приложения:

Создание приложения

Если мы хотим использовать СУБД отличную от файловой, то сначала необходимо настроить ее параметры, перейдя в соответствующий подраздел из меню консоли сервера:

Создание приложения

В нашем случае будем использовать СУБД PostgreSQL. Имя созданной базы данных можно посмотреть в свойствах приложения.

Создание приложения

По нему, например, при помощи pgadmin, можем следить за текущей нагрузкой на СУБД:

Создание приложения

После того как приложение создано и находится в статусе «работает», что видно из консоли управления сервером, можно приступить к разработке схемы интеграции:

Создание приложения

Работа в среде разработки «1С:Шина»

Описание среды разработки

Если мы установили сервер «1С:Шина» со средой разработки, то напротив каждого приложения в консоли сервера мы увидим гиперссылку с переходом в режим разработки:

Работа в среде разработки «1С:Шина»

Разработка приложения на «1С:Шина» устроена таким образом:

Из предопределенных объектов, список которых мы видим в палитре, предлагается описать бизнес-процесс интеграции различных информационных систем в виде специальной схемы.
Для этого в дереве объектов, которое располагается в левой части окна среды разработки, необходимо добавить новую подсистему, а в нее объект «Процесс интеграции»:
Далее, при помощи палитры объектов, необходимо описать источники и приемники сообщений, а также настроить связи между ними:
- В качестве источников и приемников сообщений для схемы интеграции «1С:Шины» могут выступать узлы FTP, JMS, RabbitMQ, Канал 1С, Файл:
- Также сообщения на вход схемы интеграции можно генерировать программно в обработчиках на языке похожем на «1С:Исполнитель», который использует «1С:Шина». Точкой входа для таких сообщений будет узел «Программный источник».
- Для каждого источника и приемника сообщений могут задаваться их свойства. Например, для узла «RabbitMQ источник» задается имя канала, хост, порт и т. д.
При необходимости, также используются связующие элементы 1С:Шины, предназначенные для трансляции, маршрутизации сообщений, а также подключения внешних источников данных в зависимости от бизнес-процесса интеграции.
- В качестве связующих узлов схемы интеграции могут выступать транслятор, маршрутизатор по содержимому, узел sql, узел http:
- Для связующих узлов также при необходимости задаются свойства и описываются обработчики событий, которые срабатывают при прохождении сообщения интеграции через узел:
- Значения свойств также можно описывать специальными объектами-параметрами для более удобного группового редактирования однотипных свойств:
- В обработчиках сообщений пишутся скрипты на языке похожем на 1С:Исполнитель, реализующие специфическую логику работы узла, если того требует бизнес-процесс интеграции. Пример скрипта в обработчике узла транслятор:
- В процессе написания скриптов во встроенной среде разработки 1С:Шины выполняется синтаксический контроль «на лету», что ускоряет процесс разработки и исправления ошибок.
- Подробней о языке 1С:Исполнитель и его отличиях от встроенного языка 1С:Предприятия можно прочитать в документации (its.1c.ru/db/
  execdoc). Также, существует справочник по объектной модели встроенного языка, который можно посмотреть по этой же ссылке.
Для узлов, предназначенных для обмена с 1С (или систем, которые умеют работать по протоколу AMQP 1.0), предусмотрен дополнительный объект «Группа участников», позволяющий в режиме работы приложения настроить список информационных баз, которые имеют доступ к конкретному каналу источнику или приемнику.
Движение сообщений интеграции через узлы 1С:Шины описывается элементами «Маршрут» (для связей источников и приемников между собой, а также со связующими узлами 1С:Шины) и «Связь» (для связи группы участников с каналом-источником или каналом-приемником сообщений).
Для удобства организации кода есть возможность выносить процедуры и функции в общие модули:
Также на сервере «1С:Шины» могут быть опубликованы http-сервисы, на которые могут посылать запросы внешние информационные системы, и далее при помощи программной обработки этих запросов на встроенном языке можно генерировать сообщений интеграции в узлах вида «Программный источник»:
Для публикации разрабатываемого проекта необходимо выполнить соответствующую команду из подменю, которое откроется по нажатию на название проекта в панели управления сервера:
Если проект содержит ошибки, то публикация не состоится до их исправления, список ошибок и предупреждений можно увидеть в специальной панели:

Более подробное описание каждого элемента из палитры схемы интеграции, а также описание среды разработки и сценария работы в ней можно посмотреть в документации (its.1c.ru/db/esbdoc
#content:40195:hdoc).

Групповая разработка

При разработке приложения в 1С:Шине может возникнуть необходимость использования системы контроля версии, например, когда схем интеграции несколько и каждая из них разрабатывается параллельно.

Вариантов тут несколько:

Во-первых, так как среда разработки 1С:Шины открывается из веб-интерфейса и предоставляет облачное редактирование файлов проекта, групповую разработку можно вести непосредственно в одном и том же приложении из разных сессий. Процесс примерно похож на редактирование облачных документов. Однако, стоит быть аккуратным и четко разграничивать работу внутри одного приложения, чтобы не возникло рассинхронизации при редактировании одного и того же объекта.
Во-вторых, можно использовать стороннюю систему контроля версий, например, git. Проект в «1С:Шина» физически располагается в файлах на компьютере, на котором установлен сервер интеграционной шины. Для Windows путь будет приблизительно следующий «c:\ProgramData\1C\1CE\
instances\1c-enterprise-esb-with-ide\data\i
demanager\ides\<уникальный идентификатор приложения>\workspace\src\», где <уникальный идентификатор приложения> можно посмотреть в адресной строке браузера в режиме редактирования в среде разработки:

Исходные файлы приложения «1С:Шина» обычно представлены описанием объектов и его свойств в файлах формата yaml:

Групповая разработка

При этом схемы интеграции, которые описываются в ide графически также преобразуются в данный формат:

Групповая разработка

Тексты модулей объектов и общих модулей сохраняются в приложении в формате xbsl. Директория с исходными файлами приложения может выглядеть следующим образом:

Групповая разработка

Далее, если мы хотим вести версионирование приложения, например, в git, достаточно инициализировать новый репозиторий git при помощи команды git init. Дальнейшие действия ничем не отличаются от версионирования любых проектов на git. Их можно выполнять как в графическом интерфейсе, например, через Github Desktop и другие клиенты, или же в командной строке.

Реализация практического бизнес‑кейса

Обзор схемы разузловки и маршрутизации внутри 1С:Шины

Исходя из постановки задачи и описания бизнес-процессов интеграции с требованиями к интеграционной шине данных было разработано несколько схем интеграций:

Основная схема интеграции с заказной системой, которая принимает сообщения с информацией о заказах в узлах-источниках, выполняет смену формата и замену идентификаторов в зависимости от ситуации, а также осуществляет маршрутизацию заказа исходя из его содержимого в узлы-получатели.
Схема интеграции, описывающая взаимодействие с телеграм-ботом, принимающим заказы и отправляющий сообщения интеграции в канал для программных источников сообщений в основной схеме интеграции.
Схема интеграции, описывающая передачу обратной квитанции в базу 1С-источник заказа, доставку которой интеграционная шина должна обеспечить исходя из требований.

Основная схема маршрутизации заказов

Основная схема обмена с заказной системой выглядит следующим образом:

Основная схема маршрутизации заказов

Рассмотрим подробней каждый из реализованных узлов:

Элемент «Из1С» — это узел вида «Канал1СИсточник», предназначен для приема сообщений интеграций от баз 1С источников заказов. Далее будет показано, как настроить процесс интеграции с 1С:Шиной на стороне базы 1С.
Элемент «Базы1СИсточники» — это узел вида «ГруппаУчастников», который предназначен для определения списка информационных систем, которые смогут посылать сообщения в узел-источник сообщений «Из1С». Состав группы определяется из консоли приложения:
Элемент «ИзHTTP» — это узел вида «Программный источник». Предназначен для программной генерации сообщений интеграций при поступлении запросов с заказами на http-сервис.

У http-сервиса добавлен всего один метод «sendOrder», обработчик которого принимает http запрос и генерирует сообщение интеграции:

Основная схема маршрутизации заказов

Код обработчика http-запроса, реализующий вышеописанный алгоритм на языке 1С:Исполнитель:

метод ОбработкаЗапроса(Запрос: HttpСервисЗапрос) 

    пер НужныйУзелСхемы = ОбменСЗаказнойСистемой.Схема.Узлы.ИзHttp

                                                     
    пер индWS = 1

    знч ПотокЗаписиХттп = Запрос.Ответ.ОткрытьПотокЗаписиТела()

    ПотокЗаписиХттп.Записать("Сообщение получено!")

    знч Сообщение = новый СообщениеИнтеграции({"ИзХТТП%индWS":Истина}, Запрос.Тело)

    ОбменСЗаказнойСистемой.ОтправитьСообщениеВУзлы(Сообщение, НужныйУзелСхемы)

;

Элемент «ИзКролика» — это узел вида «RabbitMQ источник», который предназначен для чтения сообщений из очереди, указанной в свойстве «Имя канала»:
Элемент «fromAMQP» — это также узел вида «Канал 1С источник», т. к. именно данный тип узла обеспечивает обмен по протоколу AMQP 1.0. В нашем бизнес-процессе мы отдельно выделили данный элемент как для логического разделения информационных баз 1С и стороннего брокера сообщений, так и по причине того, что для сообщений из данного узла нет необходимости производить смену формата. Состав информационных систем, которые имеют возможность отправить сообщения в канал определяются группой участников «ПриложенияAMQP».

Элемент «СменаФормата» — это узел вида «Транслятор», который предназначен для конвертации тела сообщения из формата json в формат xml. Обработчик преобразования на языке 1С:Исполнитель будет следующий:

метод Преобразование(Контекст: КонтекстВызова, Сообщение: ОбменСЗаказнойСистемой.Сообщение): СообщениеИнтеграции

    исп СтароеТело = Сообщение.ПолучитьТелоКакПоток()

    исп Поток      = новый ВременныйПотокЗаписи()

    КонвертацияСообщений.Json2Xml(СтароеТело, Поток)

    исп НовоеТело  = Поток.ОткрытьПотокЧтения()

    возврат Сообщение.УстановитьТелоИзПотока(НовоеТело)

;

Здесь, мы считываем тело сообщения интеграции, передаем его в процедуру преобразования в общем модуле «КонвертацияСообщений», а затем устанавливаем полученное новое тело сообщения. Код конвертации из json в xml приведен ниже:

@проект

метод Json2Xml(ПотокЖсон: ПотокЧтения, ПотокХмл: ПотокЗаписи)

    пер ВыходнойХмл = новый ЗаписьXml(ПотокХмл)

    знч ДанныеКакОбъект = СериализацияJson.ПрочитатьСоответствие(ПотокЖсон)

    ВыходнойХмл.ЗаписатьНачалоЭлемента("data")

    Xml2JsonРекурсивно(ДанныеКакОбъект, ВыходнойХмл)

    ВыходнойХмл.ЗаписатьКонецЭлемента()
        
;

метод Xml2JsonРекурсивно(ОбъектЖсон: Обходимое<любой>, ВыходнойХмл: ЗаписьXml)

    для Элемент из ОбъектЖсон

        пер ЗначениеЭлемента: любой

        пер КлючЭлемента: любой

        если Элемент это КлючИЗначение

            КлючЭлемента = Элемент.Ключ

            ЗначениеЭлемента = Элемент.Значение

            ВыходнойХмл.ЗаписатьНачалоЭлемента(КлючЭлемента)

        иначе

            ВыходнойХмл.ЗаписатьНачалоЭлемента("item")
            ЗначениеЭлемента = Элемент
        ;

        выбор ЗначениеЭлемента

        когда это Соответствие

            Xml2JsonРекурсивно(ЗначениеЭлемента, ВыходнойХмл)

        когда это Массив<любой>

            Xml2JsonРекурсивно(ЗначениеЭлемента, ВыходнойХмл)

        иначе

            ВыходнойХмл.ЗаписатьТекст(ЗначениеЭлемента.ВСтроку())
 
        ;
       
        ВыходнойХмл.ЗаписатьКонецЭлемента()
 
    ;
  
;

Элемент «ЗаменаИдентификаторов» предназначен для замены идентификаторов продукции в товарной части заказа исходя из данных внешней базы соответствия идентификаторов информационных баз, которая располагается на сервере MSSQL. Строку подключения к внешней базе данных задаем как отдельный параметр схемы интеграции:

Основная схема маршрутизации заказов

Подключение к базе данных будет происходить через jdbc connector, строка подключения будет выглядеть следующим образом:

jdbc:sqlserver://server_name;databaseName=base_name;user=user_name;password=user_password

Здесь server_name — имя сервера СУБД MSSQL, base_name — имя базы данных, user_name и user_password — логин и пароль от пользователя базы данных соответственно.

Далее реализуем обработчик «Обработка сообщения», в котором и будет произведено преобразование:

метод ЗаменаИдентификаторовОбработкаСообщения(Контекст: ОбменСЗаказнойСистемой.КонтекстВызова, Сообщение: ОбменСЗаказнойСистемой.Сообщение, Соединение: СоединениеSql): СообщениеИнтеграции

    исп СтароеТело = Сообщение.ПолучитьТелоКакПоток()

    исп Поток      = новый ВременныйПотокЗаписи()

    КонвертацияСообщений.ЗаменитьГуидыТоваровХмл(СтароеТело, Поток, Соединение)

    исп НовоеТело  = Поток.ОткрытьПотокЧтения()

    возврат Сообщение.УстановитьТелоИзПотока(НовоеТело)

;

Алгоритм схож с обработчиком транслятора сообщения с той разницей, что в данном обработчике доступно соединение с базой данных, которое мы передаем в качестве параметра в функцию “ЗаменитьГуидыТоваровХмл” в общем модуле “КонвертацияСообщений”:

@проект

метод ЗаменитьГуидыТоваровХмл(ВходнойПоток:  ПотокЧтения, ВыходнойПоток: ПотокЗаписи, Соединение: СоединениеSql)

    пер ВыходнойХмл = новый ЗаписьXml(ВыходнойПоток)

    пер ВходнойХмл = новый ЧтениеXml(ВходнойПоток)

    пер ТекущееИмя = ""

    пер ЗначениеЭлемента  = ""

    пер ТекПространствоИмен  = ""

    пока ВходнойХмл.Следующий()

        выбор ВходнойХмл.ВидУзла

        когда ВидУзлаXml.НачалоЭлемента

             ТекущееИмя = ВходнойХмл.Имя

             ТекПространствоИмен = ВходнойХмл.ПространствоИмен

             ВыходнойХмл.ЗаписатьНачалоЭлемента(ТекущееИмя, ТекПространствоИмен)

        когда ВидУзлаXml.КонецЭлемента

             ВыходнойХмл.ЗаписатьКонецЭлемента() 

        когда ВидУзлаXml.Текст

             ЗначениеЭлемента = ВходнойХмл.Значение

             если ТекущееИмя == "product_id"

                 ЗначениеЭлемента = КоннекторSQL.ИдентификаторПолучателя(Соединение,  ВходнойХмл.Значение)

             иначе если ТекущееИмя == "product_name"

                 ЗначениеЭлемента = КоннекторSQL.ИдентификаторПолучателя(Соединение,  ВходнойХмл.Значение, "ITEM") 

                 ТекущееИмя = "product_id"

             иначе

                 ЗначениеЭлемента = ВходнойХмл.Значение   

             ;  

             ВыходнойХмл.ЗаписатьТекст(ЗначениеЭлемента)

        ;       

    ;       

;

Функция «КоннекторSQL.ИдентификаторПолучателя» и будет обращаться к базе данных для получения идентификатора продукции в базе-получателе:

@проект

метод ИдентификаторПолучателя(Соединение: СоединениеSql, ИдентификаторИсточника: Строка, ИмяПоля: Строка = "IDSOURCE"): Строка

    пер ТекстЗапроса = "SELECT [IDSOURCE],[IDRECEIVER],[ITEM] FROM [sergav_BaseMappingSQL].[dbo].[Mapping] where [" + ИмяПоля + "] = &id"

    пер ВыборкаIDRECEIVER = Соединение.СоздатьЗапросСВыборкой(ТекстЗапроса)

    ВыборкаIDRECEIVER.УстановитьЗначениеПараметра("id", ИдентификаторИсточника)

    пер ИдентификаторПолучателя: Строка

    ИдентификаторПолучателя = ""

    область

        исп Рез = ВыборкаIDRECEIVER.Выполнить()

        если Рез.Следующий()

            ИдентификаторПолучателя = Рез.Получить("IDRECEIVER") как Строка

        ;

    ;

    возврат ИдентификаторПолучателя

;

Элемент «Маршрутизатор
ПоТипуЗаказа» — это узел вида «Маршрутизатор
ПоСодержимому», который реализует логику выбора узла-получателя в зависимости от типа заказа, указанного в свойстве «type» в теле сообщения. Обработчик определения получателей будет следующим:

метод ВыборПолучателей(Контекст:  КонтекстВызова, Сообщение: ОбменСЗаказнойСистемой.Сообщение): Коллекция<УзелСхемы>

    пер Результат = новый Массив<УзелСхемы>()

    пер ВидЗаказа =  РаботаСДаннымиСообщений.ВидЗаказаВСообщении(Сообщение)

    выбор ВидЗаказа

    когда РаботаСДаннымиСообщений.ВидыЗаказов.ЗаказБэка

         Результат.Добавить(ОбменСЗаказнойСистемой.Схема.Узлы.ВУпо) 

    когда  РаботаСДаннымиСообщений.ВидыЗаказов.ЗаказФронта

         Результат.Добавить(ОбменСЗаказнойСистемой.Схема.Узлы.ВФастФуд)

    когда РаботаСДаннымиСообщений.ВидыЗаказов.ОбщийЗаказ

         Результат.Добавить(ОбменСЗаказнойСистемой.Схема.Узлы.ВУпо)

         Результат.Добавить(ОбменСЗаказнойСистемой.Схема.Узлы.ВФастФуд)   

    ;

    возврат Результат

;

Вид заказа определяется функцией «ВидЗаказа
ВСообщении» в общем модуле «РаботаСДанными
Сообщений». Также, в этом модуле определяется перечисление «ВидыЗаказов»:

@проект

перечисление ВидыЗаказов

    ЗаказБэка,

    ЗаказФронта,

    ОбщийЗаказ
    
;

конст ИМЯ_ТЕГА_ТИП_ЗАКАЗА = "type"

@проект

метод ВидЗаказаВСообщении(Сообщение: СообщениеИнтеграции): ВидыЗаказов?

    исп ПотокХмл = Сообщение.ПолучитьТелоКакПоток()

    пер ЧтениеСообщения = новый ЧтениеXml(ПотокХмл)

    пока ЧтениеСообщения.Следующий()

        если ЧтениеСообщения.ВидУзла == ВидУзлаXml.НачалоЭлемента и ЧтениеСообщения.Имя == ИМЯ_ТЕГА_ТИП_ЗАКАЗА

            ЧтениеСообщения.Следующий()

            попытка
 
                возврат ВидыЗаказов.ПоИмени(ЧтениеСообщения.Значение)

            поймать Искл: Исключение

                возврат Неопределено

            ;

        ;

    ;

    возврат Неопределено

;

Элементы «В УПО» и «В ФастФуд» — это узлы вида «Канал 1С назначение», которые предназначены для отправки сообщений интеграции в базы получатели. Состав информационных баз определяется группами участников «Базы УПО» и «Базы ФастФуд» соответственно.

Интеграция с ботом Telegram

Схема интеграции, описывающая взаимодействие с телеграм-ботом выглядит следующим образом:

Интеграция с ботом Telegram

В данной схеме, логикой чтения сообщений из чата Telegram и построения сообщения с данными о заказе занимается непосредственно «1С:Шина». Для этого точкой входа в данной схеме интеграции будет таймер, который по заданному интервалу времени будет инициализировать сообщение интеграции.

Далее в узле «Транслятор» будет произведено:

Подключение к Telegram API по протоколу HTTP и считывание последних непрочитанных сообщений:
Формирование заказов и их программную отправку в виде сообщений интеграций в узел «ИзHTTP» в основной схеме интеграции обмена заказами:
Идентификатор последнего считанного из Telegram сообщения будем хранить в файле update_id, который добавлен в проект в качестве ресурса:

Содержимое файла в формате json хранит единственное свойство с идентификатором:

Отметим также, что элемент «Заземление» — это узел вида «Файл назначение», который необходим для фиксации сообщения интеграции, сгенерированного таймером. Данное сообщение является служебным и необходимо для активации алгоритма обработки сообщений из Telegram. Для того, чтобы такое сообщение достигло назначения и добавлен узел заземления.

Схема обратной квитанции

Схема интеграции, описывающая передачу обратной квитанции в базу 1С, являющейся источником заказа, выглядит следующим образом:

Схема обратной квитанции

Схема реализует простую передачу сообщений из канала-источника в канал-получатель без дополнительной маршрутизации. В группах участников «Отдающие обратную квитанцию» будут те же информационные базы, которые являются получателями сообщений на основной схеме интеграции, а в группе «Получающие обратную квитанцию» будут информационные базы, которые являются также источником сообщений на основной схеме.

Настройка обработки и отправки сообщений на стороне информационных баз 1С

Для обмена сообщениями с 1С:Шиной в платформе «1С:Предприятие» предусмотрены специальные объекты метаданных — «Сервисы интеграции».

В нашем случае, необходимо создать и настроить работу с сообщениями:

Отправку сообщений в информационной базе 1С источнике данных о заказах.
Получение и обработку сообщений в информационных базах получателях.
Отправку обратной квитанций.
Ролучение и обработку обратной квитанции.

Отправка сообщений из базы-источника заказов

Итак, в базе-источнике данных о заказах добавляем новый сервис интеграции. Сделать это можно как непосредственно в конфигурации информационной базы, так и в расширении. В свойствах объекта необходимо указать адрес внешнего сервиса интеграции — то есть адрес приложения на сервере 1С:Шины. Копируем его из адресной строки браузера находясь в консоли сервера: